SPACE 1/SPACE - Library 1 - Volume 1.iso/misc~1/447/dreidel/dreidel.lst

File List | 1990-02-04 | 21KB | 979 lines

'
' **********************************************************************
'                              D R E I D E L
'                       A Traditional Game of Chance
'                   yet another kidprg in GFA Basic from
'                               D.A. Brumleve
'                    Copyright 1989 by Analog Computing
' **********************************************************************
'                               Version 1.2
'                              July 24, 1989
' **********************************************************************
'                                REFERENCE
' Significant variables:
' Spinner$(1-4)=the four sprites used to show the dreidel spinning
' Dreidel$(1-4)=the four sides of the dreidel
' Dreidel%=the randomly-chosen "up" side of the dreidel when spun
' Spin%=the randomly-chosen number of rotations of the dreidel when spun
' Token$=the sprite imitating a coin or token for use in scoring
' Token%(1-2)=the number of tokens held by each player
' Pot_token%=the number of tokens in the pot
' Position_token%(0-2,0-9)=indicates whether or not a particular position
'         in each player's token area contains a token
' Clor%(1-2)=the color associated with Players 1 and 2
' Player%=the number (1 or 2) of the current player
' Position_pot_token%(0-10)=indicates location of token in the pot
'
' **********************************************************************
'
' ***************************** INITIALIZATION *************************
Dim Palette%(15)
Num%=5
Dim Clip_len%(Num%),Colr_len%(Num%),Colr$(Num%)
Dim Clip_width%(Num%),Clip_hite%(Num%),Rez_pic%(Num%)
Dim Clor%(2)
Dim Lttlepic$(5),Dreidel$(5),Spinner$(4),Lttr$(12),Offset%(2)
Dim Token%(2),Position_token%(2,9),Position_pot_token%(10),Player_name$(2)
@Check_rez
Hidem
@Save_palette
@Black_screen
Filename$="SPIN.DAT"
Num%=4
@Load_spinner
For I%=1 To 4
  Spinner$(I%)=Lttlepic$(I%)
Next I%
Filename$="DREIDEL.DAT"
Num%=5
@Load_spinner
For I%=1 To 4
  Dreidel$(I%)=Lttlepic$(I%)
Next I%
Token$=Lttlepic$(5)
Graphmode 2
@Main_screen
@Title
Cls
Setcolor 7,2,2,2
Sput Screen$
Clor%(1)=5
Clor%(2)=1
Defmouse 3
@Player_name
'
' **************************** MAIN PROGRAM ****************************
Do
  @Beginning_set_up
  @Start_round
  Do
    @Spin_the_dreidel
    Exit If Game_over%=1
  Loop
Loop
'
' ***************************** SPIN ***********************************
Procedure Spin_the_dreidel
  T$=Player_name$(Player%)+", spin the dreidel."
  Deftext Clor%(Player%),0,0,13
  Text 53+Offset%(Player%),72,T$
  Color Clor%(Player%)
  Box 108,81,211,199
  Pb%=Player%
  @Player_box
  Try_again:
  Showm
  @Let_go
  Repeat
    Mouse Mx%,My%,Mk%
  Until Mk%>0
  If Mx%>0 And Mx%<44 And My%>0 And My%<18 And Mk%>0
    @Wanna_quit
    Goto Try_again
  Endif
  If Mx%>275 And Mx%<319 And My%>0 And My%<18
    @Info
    Goto Try_again
  Endif
  If Mx%>108 And Mx%<211 And My%>81 And My%<199
    @Clear_instructions
    @Clear_dreidel_box
    Hidem
    Dreidel%=Random(4)+1
    Spin%=(Random(5)+1)*2
    Sound 1,0,1,4,0
    Wave 1,1,8,1000,0
    For I%=1 To Spin%
      For J%=1 To 3
        Put 109,82,Spinner$(J%)
        Pause 2
      Next J%
    Next I%
    Put 109,82,Spinner$(4)
    Pause 7
    Wave 0,0
    Put 135,94,Dreidel$(Dreidel%)
    Restore Dreidel_data
    For I%=1 To 4
      Read D$,L%
      If Dreidel%=I%
        Spin_score$=D$
        Lx%=L%
      Endif
    Next I%
    Deftext Clor%(Player%),0,0,13
    Text Lx%,72,Spin_score$
  Else
    @Buzz_sound
    Goto Try_again
  Endif
  If Dreidel%=1
    Pause 150
  Endif
  If Dreidel%=2
    @Gimmel
  Endif
  If Dreidel%=3
    @Heh
  Endif
  If Dreidel%=4
    @Shin
  Endif
  @Clear_instructions
  @Clear_player_box
  If Pot_token%=0
    @Round_over
    @Start_round
  Endif
  If Pot_token%=1
    @Round_over
    @Start_round
  Endif
  If Game_over%=1
    Goto New_game
  Endif
  @New_player
  New_game:
Return
'
' ******************************* ROUNDS *******************************
Procedure Beginning_set_up
  Game_over%=0
  Pot_token%=0
  Put 109,82,Spinner$(1)
  For I%=1 To 10
    Position_pot_token%(I%)=0
  Next I%
  For I%=1 To 2
    Token%(I%)=5
  Next I%
  Deffill 0
  Pbox 1,22,318,52
  Pbox 1,82,104,177
  Pbox 215,82,318,177
  Ly%=110
  Restore Beginning_set_up_data1
  For J%=1 To 2
    For I%=1 To 5
      Read Lx%,Ly%
      Put Lx%,Ly%-21,Token$
    Next I%
    Restore Beginning_set_up_data2
  Next J%
  For J%=1 To 2
    For I%=1 To 5
      Position_token%(J%,I%)=1
    Next I%
  Next J%
  For J%=1 To 2
    For I%=6 To 9
      Position_token%(J%,I%)=0
    Next I%
  Next J%
  Deftext 5,0,0,6
  Text 20+Offset%(1),193,Player_name$(1)
  Deftext 1,0,0,6
  Text 233+Offset%(2),193,Player_name$(2)
  Player%=Random(2)+1
Return
'
Procedure New_player
  If Player%=1
    Player%=2
  Else
    Player%=1
  Endif
Return
'
Procedure Start_round
  For I%=1 To 2
    P%=I%
    If Token%(P%)<1
      O_t$="any tokens!"
      @Out_of_tokens
    Endif
    Exit If Game_over%=1
  Next I%
  If Game_over%=1
    Goto Good_luck
  Endif
  Showm
  For I%=1 To 2
    Deftext Clor%(I%),0,0,13
    P%=I%
    T$=Player_name$(I%)+", put a token in the pot."
    Text 27+Offset%(I%),72,T$
    Pb%=I%
    P%=I%
    @Player_box
    @Put_token_in_the_pot
    @Clear_player_box
    @Clear_instructions
  Next I%
  Good_luck:
Return
'
Procedure Round_over
  Hidem
  Deftext 12,0,0,13
  Text 51,72,"The pot needs more tokens!"
  Pause 25
  @Alert_sound
  Pause 50
  @Clear_instructions
Return
'
' ********************************* POT ********************************
Procedure Put_token_in_the_pot
  Got_one%=0
  Color Clor%(P%)
  If P%=1
    Box 0,81,105,178
  Else
    Box 214,81,319,178
  Endif
  Showm
  Do
    Start:
    @Let_go
    Repeat
      Mouse Mx%,My%,Mk%
    Until Mk%>0
    If Mx%>0 And Mx%<44 And My%>0 And My%<18 And Mk%>0
      @Wanna_quit
      Goto Start
    Endif
    If Mx%>275 And Mx%<319 And My%>0 And My%<18
      @Info
      Goto Start
    Endif
    If P%=1
      Restore Player1_token_position_data
    Else
      Restore Player2_token_position_data
    Endif
    For K%=1 To 9
      Read Lx%,Ly%,Rx%,Ry%,P_t%
      If Mx%>Lx% And Mx%<Rx% And My%>Ly%-21 And My%<Ry%-21 And Position_token%(P%,P_t%)=1
        Deffill 0
        Pbox Lx%+1,Ly%+1-21,Rx%-1,Ry%-1-21
        Position_token%(P%,P_t%)=0
        Dec Token%(P%)
        Got_one%=1
      Endif
      Exit If Got_one%=1
    Next K%
    If Got_one%=0
      @Buzz_sound
    Endif
    Exit If Got_one%=1
  Loop
  Hidem
  @Clear_token_box
  Inc Pot_token%
  @Add_pot_token
Return
'
Procedure Take_token_from_the_pot
  Got_one%=0
  Color Clor%(Player%)
  Box 0,21,319,53
  Showm
  Do
    Start2:
    @Let_go
    Repeat
      Mouse Mx%,My%,Mk%
    Until Mk%>0
    If Mx%>0 And Mx%<44 And My%>0 And My%<18 And Mk%>0
      @Wanna_quit
      Goto Start2
    Endif
    If Mx%>275 And Mx%<319 And My%>0 And My%<18
      @Info
      Goto Start2
    Endif
    Restore Pot_token_position_data
    For J%=1 To 10
      Read Lx%
      If Mx%>Lx% And Mx%<Lx%+31 And My%>21 And My%<53 And Position_pot_token%(J%)=1
        Dec Pot_token%
        Position_pot_token%(J%)=0
        Deffill 0
        Pbox Lx%,22,Lx%+31,52
        Got_one%=1
      Endif
    Next J%
    If Got_one%=0
      @Buzz_sound
    Endif
    Exit If Got_one%=1
  Loop
  Hidem
  Got_one%=0
  If Player%=1
    Restore Beginning_set_up_data1
  Else
    Restore Beginning_set_up_data2
  Endif
  For K%=1 To 9
    Read Lx%,Ly%
    If Position_token%(Player%,K%)=0
      Position_token%(Player%,K%)=1
      Put Lx%,Ly%-21,Token$
      @Other_sound
      Inc Token%(Player%)
      Got_one%=1
    Endif
    Exit If Got_one%=1
  Next K%
  @Clear_pot_box
Return
'
Procedure Add_pot_token
  Got_one%=0
  Restore Pot_token_position_data
  For L%=1 To Pot_token%
    Read Lx%
    If Position_pot_token%(L%)=0
      Put Lx%+1,24,Token$
      @Other_sound
      Position_pot_token%(L%)=1
      Got_one%=1
    Endif
    Exit If Got_one%=1
  Next L%
Return
'
Procedure Gimmel                         ! take all of the pot
  Token_share%=Pot_token%
  If Token%(Player%)+Token_share%=10
    Pause 75
    @Clear_instructions
    T$=Player_name$(Player%)+" has all the tokens!"
    For Q%=1 To 4
      Deftext Q%+1,0,0,13
      If Q%=4
        Deftext 12,0,0,13
      Endif
      Text 48+Offset%(Player%),72,T$
      Sound 1,15,1,4,4
      Sound 1,15,8,4,10
      Sound 1,0,0,0,0
      Pause 10
    Next Q%
    Pause 30
    Winner%=Player%
    @Win
  Endif
  If Game_over%=1
    Goto Won_it
  Endif
  For I%=1 To Token_share%
    @Take_token_from_the_pot
  Next I%
  Won_it:
Return
'
Procedure Heh                            ! take half of the pot
  If Pot_token%=3 Or Pot_token%=5 Or Pot_token%=7 Or Pot_token%=9
    P_t%=Pot_token%+1
  Else
    P_t%=Pot_token%
  Endif
  Token_share%=P_t%/2
  For I%=1 To Token_share%
    @Take_token_from_the_pot
  Next I%
Return
'
Procedure Shin                           ! put 1 token in the pot
  P%=Player%
  If Token%(Player%)<2
    O_t$="two tokens!"
    @Out_of_tokens
  Endif
  If Game_over%=1
    @Clear_instructions
    Goto Maybe_next_time
  Endif
  For Q%=1 To 2
    @Put_token_in_the_pot
  Next Q%
  Maybe_next_time:
Return
'
Procedure Out_of_tokens
  Pause 100
  @Clear_instructions
  Deftext 12,0,0,13
  T$=Player_name$(P%)+" doesn't have "+O_t$
  Text 27+Offset%(P%),72,T$
  @Dud_sound
  Pause 100
  If P%=1
    Winner%=2
  Else
    Winner%=1
  Endif
  @Win
Return
'
Procedure Win
  @Clear_instructions
  Deftext 12,0,0,13
  T$=Player_name$(Winner%)+" has won the game!"
  Text 57+Offset%(Winner%),72,T$
  First_time%=0
  Pause 20
  @Dreidel_music
  @Clear_instructions
  Game_over%=1
Return
'
' **************************** INSTRUCTIONS ****************************
Procedure Clear_instructions
  Deffill 0
  Pbox 1,57,318,77
  Pause 10
Return
'
Procedure Player_box
  Deffill Clor%(Pb%)
  If Pb%=1
    Fill 2,198
  Else
    Fill 216,198
  Endif
Return
'
Procedure Clear_player_box
  Deffill 0
  Fill 2,198
  Fill 216,198
Return
'
Procedure Clear_token_box
  Color 8
  Box 0,81,105,178
  Box 214,81,319,178
Return
'
Procedure Clear_dreidel_box
  Color 8
  Box 108,81,211,199
Return
'
Procedure Clear_pot_box
  Color 8
  Box 0,21,319,53
Return
'
' ****************************** DIALOGS *******************************
Procedure Info
  Hidem
  Sget Screen$
  Deffill 10
  Fill 276,1
  @Select_sound
  @Alert_box
  @Let_go
  Deftext 5,0,0,6
  Text 8,70,"  The dreidel is a spinning top with"
  Text 5,80,"  four sides.  Each side has a Hebrew"
  Text 7,90,"  letter on it.  Players take tokens"
  Text 16,100,"  from the pot--or put tokens in--"
  Text 10,110,"  depending on the letter facing up"
  Text 7,120,"  when the top stops spinning.  When"
  Text 7,130,"  the pot has fewer than two tokens,"
  Text 11,140,"    each player puts a token in."
  Deftext 13,0,0,6
  Text 10,152," D.A. Brumleve's Compukid Connection"
  Text 14,162,"column in Analog Computing can bring"
  Text 14,172,"kidprgs to your mailbox every month."
  Text 11,182,"  Call [phone] to subscribe!"
  Deftext 5,1,0,4
  Text 10,192,"     <<  PRESS MOUSE BUTTON TO CONTINUE.  >>"
  @Let_go
  Repeat
  Until Mousek
  Sput Screen$
  @Let_go
  Showm
Return
'
Procedure Wanna_quit
  Deffill 2
  Fill 2,2
  @Select_sound
  @Save_routine
  Deffill 0
  Fill 2,2
  @Let_go
Return
'
Procedure Alert_box
  Deffill 1
  Pbox 0,56,319,199
  Color 5
  Box 0,56,319,199
  Box 1,57,318,198
  Box 3,59,316,196
Return
'
Procedure Save_routine
  Sget Screen$
  @Alert_box
  @Save_alert
  Deftext 0,0,0,6
  Text 52,100,"Do you really want to quit?"
  @Let_go
  Repeat
    Mouse Mmx%,Mmy%,Mmk%
  Until Mmk%>0 And Mmy%>118 And Mmy%<172 And ((Mmx%>48 And Mmx%<122) Or (Mmx%>197 And Mmx%<271))
  @Select_sound
  Deffill 5
  If Mmx%>48 And Mmx%<122
    Hidem
    Fill 49,119
    Pause 15
    @Finale_sound
    Cls
    @Restore_palette
    Showm
    End
  Else
    Fill 198,119
    Pause 15
    Sput Screen$
  Endif
Return
'
Procedure Save_alert
  Color 5
  Box 48,118,122,172
  Box 197,118,271,172
  Box 201,122,267,168
  Deffill 5
  Pbox 52,122,118,168
  Deftext 0,0,0,13
  Text 70,150,"Yes!"
  Text 225,150,"No."
Return
'
' ************************* INPUT PLAYERS' NAMES ***********************
Procedure Player_name
  For Q%=1 To 2
    @Alert_box
    P_n$="Player "+Str$(Q%)+", type your name"
    Deftext 0,0,0,6
    Text 65,100,P_n$
    Text 85,110,"and press <Return>."
    @Get_name
    Player_name$(Q%)=Nw_word$
  Next Q%
  For I%=1 To 2
    If Player_name$(I%)=""
      Player_name$(I%)="PLAYER "+Str$(I%)
    Endif
  Next I%
  For J%=1 To 2
    Got_one%=0
    For I%=1 To 8
      If Len(Player_name$(J%))=I%
        Offset%(J%)=((8-I%)*8)/2
        Got_one%=1
      Endif
      Exit If Got_one%=1
    Next I%
  Next J%
  Sput Screen$
  Showm
Return
'
Procedure Get_name
  Deftext 0,0,0,13
  Gx%=111
  For I%=1 To 8
    Text Gx%,154,"_ "
    Add Gx%,11
  Next I%
  Get 5,50,161,193,Temp_screen$
  A%=0
  Hidem
  For I%=1 To 8
    Lttr$(I%)=""
  Next I%
  Ltter_count%=1
  Nw_word$=""
  Gx%=110
  Df%=1
  Repeat
    Backed_up:
    Repeat
    Until Inkey$=""
    A%=Inp(2)
    ' If the user presses the Backspace key, the last letter typed is erased.
    If A%=8
      Put 5,50,Temp_screen$
      Lttr$(Ltter_count%-1)=""
      Deffill Df%,2,8
      Pbox 100,125,200,152
      If Ltter_count%>1
        Dec Ltter_count%
        Sub Gx%,11
        Lx%=110
        For I%=1 To Ltter_count%
          Deftext 0,0,0,13
          Text Lx%,150,Lttr$(I%)
          Add Lx%,11
        Next I%
      Endif
      Goto Backed_up
    Endif
    ' The following clause renumbers the ASCII code of the letter typed
    ' if the user is typing in lower case.
    If A%>90
      A%=A%-32
    Endif
    If A%>63 And A%<91 And Ltter_count%<9
      Lttr$(Ltter_count%)=Chr$(A%)
      Deftext 0,0,0,13
      Text Gx%,150,Lttr$(Ltter_count%)
      Inc Ltter_count%
      Add Gx%,11
    Endif
    Pause 5
  Until A%=13
  Dec Ltter_count%
  For I%=1 To Ltter_count%
    Nw_word$=Nw_word$+Lttr$(I%)
  Next I%
Return
'
' *************************** DISK ACTIVITIES **************************
Procedure Load_spinner
  Zz%=1
  If Not Exist(Filename$)
    @Restore_palette
    T$=" |You must have "+Filename$+"|in the same directory and"+"|drive to run this program!"
    Alert 3,T$,1,"Oops!",Dummy%
    End
  Endif
  Open "I",#1,Filename$
  For X%=1 To Num%
    Hidem
    Input #1,Clip_len%(X%),Colr_len%(X%),Clip_width%(X%),Clip_hite%(X%),Rez_pic%(X%)
    Lttlepic$(X%)=String$(Clip_len%(X%),0)
    Colr$(X%)=String$(Colr_len%(X%),0)
    Bget #1,Varptr(Colr$(X%)),Colr_len%(X%)
    Bget #1,Varptr(Lttlepic$(X%)),Clip_len%(X%)
    Add Zz%,1
  Next X%
  Close #1
Return
'
' ******************************* SCREENS ******************************
Procedure Title
  Cls
  Deftext 5,1,0,13
  Text 145,50,"D R E I D E L"
  Deftext 1,0,0,6
  Text 109,75,"  A Traditional Game"
  Text 111,90,"      of Chance"
  Ss%=110
  Deftext 12,1,0,4
  Text 45,35+Ss%,"YET ANOTHER KIDPRG  IN GFA BASIC FROM"
  Deftext 12,0,0,4
  Text 155,35+Ss%,Chr$(191)
  Deftext 2,0,0,6
  Text 35,45+Ss%,"         D.A. Brumleve"
  Deftext 15,5,0,4
  Text 52,54+Ss%,"                  ANALOG COMPUTING"
  Deftext 15,1,0,4
  Text 52,54+Ss%,"COPYRIGHT 1989 BY"
  Deftext 2,1,0,4
  Text 60,63+Ss%,"          VERSION 1.2"
  Ss%=80
  Deftext 5,0,0,6
  Text 35,115+Ss%,"As published originally in    !"
  Sty%=46+Ss%
  Stx%=48
  Color 1
  Box 204+Stx%,52+Sty%,224+Stx%,73+Sty%
  Color 5
  Box 205+Stx%,53+Sty%,223+Stx%,72+Sty%
  Deffill 5,2,8
  Pbox 205+Stx%,66+Sty%,223+Stx%,72+Sty%
  Deffill 1,2,8
  Pbox 206+Stx%,54+Sty%,222+Stx%,65+Sty%
  Deftext 5,1,0,13
  Text 207+Stx%,65+Sty%," T"
  Text 205+Stx%,65+Sty%,"S"
  Deftext 1,1,0,4
  Text 205+Stx%,71+Sty%,"LOG"
  Put 20,0,Spinner$(1)
  Void Xbios(6,L:Varptr(Colr$(4)))
  Pause 20
  Sound 1,0,1,4,0
  Wave 1,1,8,1000,0
  For I%=1 To 6
    For J%=1 To 3
      Put 20,0,Spinner$(J%)
      Pause 2
    Next J%
  Next I%
  Put 20,0,Spinner$(4)
  Pause 7
  Wave 0,0
  Put 46,12,Dreidel$(1)
  Pause 30
  Deftext 12,0,0,6
  First_time%=1
  @Dreidel_music
  Pause 70
Return
'
Procedure Main_screen
  Restore Screen_box_data
  For I%=1 To 12
    Read Lx%,Ly%,Rx%,Ry%,C%
    Color C%
    Box Lx%,Ly%,Rx%,Ry%
  Next I%
  Deftext 5,0,0,6
  Text 133,6,"DREIDEL"
  Deftext 1,0,0,4
  Text 98,14,"FROM ANALOG COMPUTING"
  Deffill 2
  Fill 4,4
  Deftext 0,0,0,6
  Text 7,12,"EXIT"
  Deffill 10
  Fill 315,5
  Deftext 0,0,0,6
  Text 281,12,"INFO"
  Sget Screen$
Return
'
' **************************** WATCH THE MOUSE *************************
Procedure Let_go
  Repeat
    Mouse Ax%,Ay%,Ak%
  Until Ak%=0
Return
'
' ***************************** COLOR PALETTE **************************
Procedure Check_rez
  Rez%=Xbios(4)
  If Rez%<>0
    Alrt$=" |    D R E I D E L |requires Low Resolution."
    Alert 3,Alrt$,1,"Oops!",Dummy%
    End
  Endif
Return
'
Procedure Save_palette
  For I%=0 To 15
    Palette%(I%)=Xbios(7,W:I%,W:-1)
  Next I%
Return
'
Procedure Restore_palette
  For I%=0 To 15
    Setcolor I%,Palette%(I%)
  Next I%
Return
'
Procedure Black_screen
  For I%=0 To 15
    Setcolor I%,0,0,0
  Next I%
Return
'
' ******************************* SOUNDS *******************************
Procedure Dreidel_music
  Restore Dreidel_name_data
  For I%=1 To 32
    If I%=1 Or I%=9 Or I%=17 Or I%=26
      Read D$,Lx%,Nn%
      If First_time%=1
        Deffill 0
        Pbox 30,110,95,125
        Put 46,12,Dreidel$(Nn%)
        Text Lx%,120,D$
      Else
        If Nn%=4
          Nn%=11
        Endif
        Deftext Nn%+1,0,0,13
        Text 57+Offset%(Winner%),72,T$
      Endif
    Else
      Read Nt%,Dur%
      If Nt%=0
        Pause Dur%*3
        Goto Skipit
      Endif
      Sound 1,15,Nt%,4,Dur%*3
      Sound 1,0,0,0,1
      Skipit:
    Endif
  Next I%
Return
'
Procedure Select_sound
  Sound 1,15,6,3,2
  Sound 1,15,6,4,2
  Sound 1,15,8,4,6
  Sound 1,0,0,0,0
Return
'
Procedure Buzz_sound
  Sound 1,15,1,3,5
  Sound 1,0,0,0,0
Return
'
Procedure Other_sound
  Sound 1,15,6,5,2
  Sound 1,0,0,0,0
Return
'
Procedure Finale_sound
  Pause 10
  Restore Finale_data
  For I%=1 To 6
    Read Nt%,Dur%
    Sound 1,15,Nt%,4,Dur%*3
    Sound 1,0,0,0,1
  Next I%
Return
'
Procedure Dud_sound
  For Oct%=4 Downto 1
    For Nt%=12 Downto 1
      Sound 1,15,Nt%,Oct%,2
    Next Nt%
  Next Oct%
  Sound 1,0,0,0,0
Return
'
Procedure Alert_sound
  Sound 1,15,10,3,10
  Sound 1,15,3,3,5
  Sound 1,0,0,0,0
Return
'
' ******************************** DATA ********************************
Screen_box_data:
Data 0,0,44,18,9
Data 3,3,41,15,9
Data 275,0,319,18,9
Data 278,3,316,15,9
Data 0,21,319,53,8
Data 0,181,105,199,9
Data 3,184,102,196,9
Data 0,81,105,178,8
Data 108,81,211,199,8
Data 214,181,319,199,9
Data 217,184,316,196,9
Data 214,81,319,178,8
'
Dreidel_data:
Data Nun: you don't lose or gain any tokens.,5
Data Gimmel: take all the tokens in the pot!,5
Data Heh: take half the tokens in the pot!,12
Data Shin: put two tokens in the pot.,35
Beginning_set_up_data1:
Data 9,108,39,108,69,108,9,138,39,138,69,138,9,168,39,168,69,168
Beginning_set_up_data2:
Data 223,108,253,108,283,108,223,138,253,138,283,138,223,168,253,168,283,168
'
Pot_token_position_data:
Data 5,35,66,97,128,159,190,221,252,283,319
'
Player1_token_position_data:
Data 0,102,37,136,1
Data 37,102,67,136,2
Data 67,102,105,136,3
Data 0,136,37,166,4
Data 37,136,67,166,5
Data 67,136,105,166,6
Data 0,166,37,199,7
Data 37,166,67,199,8
Data 67,166,105,199,9
'
Player2_token_position_data:
Data 214,102,251,136,1
Data 251,102,281,136,2
Data 281,102,319,136,3
Data 214,136,251,166,4
Data 251,136,281,166,5
Data 281,136,319,166,6
Data 214,166,251,199,7
Data 251,166,281,199,8
Data 281,166,319,199,9
'
Dreidel_name_data:
Data nun,58,1
Data 8,4
Data 5,4
Data 8,4
Data 5,4
Data 8,4
Data 5,4
Data 0,4
Data gimmel,47,2
Data 6,4
Data 8,4
Data 8,4
Data 6,4
Data 5,4
Data 6,8
Data 0,4
Data heh,59,3
Data 10,4
Data 6,4
Data 3,4
Data 6,4
Data 3,4
Data 6,4
Data 3,4
Data 0,4
Data shin,54,4
Data 8,4
Data 8,4
Data 6,4
Data 5,4
Data 3,4
Data 1,8
'
Finale_data:
Data 8,4
Data 8,4
Data 6,4
Data 5,4
Data 3,4
Data 1,8
'